macos.mm

Go to the documentation of this file.

/*
 * This file is part of OpenTTD.
 * OpenTTD is free software; you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation, version 2.
 * OpenTTD is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
 * See the GNU General Public License for more details. You should have received a copy of the GNU General Public License along with OpenTTD. If not, see <https://www.gnu.org/licenses/old-licenses/gpl-2.0>.
 */

 
#include "../../stdafx.h"
#include "../../core/bitmath_func.hpp"
#include "../../rev.h"
#include "macos.h"
#include "../../string_func.h"
#include "../../fileio_func.h"
#include <pthread.h>
#include "macos_objective_c.h"
 
#ifdef WITH_COCOA
static NSAutoreleasePool *_ottd_autorelease_pool;
#endif

std::tuple<int, int, int> GetMacOSVersion()
{
  NSOperatingSystemVersion ver = [ [ NSProcessInfo processInfo ] operatingSystemVersion ];
  return { static_cast<int>(ver.majorVersion), static_cast<int>(ver.minorVersion), static_cast<int>(ver.patchVersion) };
}
 
#ifdef WITH_COCOA
extern void CocoaDialog(std::string_view title, std::string_view message, std::string_view buttonLabel);
#endif

void ShowMacDialog(std::string_view title, std::string_view message, std::string_view buttonLabel)
{
#ifdef WITH_COCOA
  CocoaDialog(title, message, buttonLabel);
#else
  fmt::print(stderr, "{}: {}\n", title, message);
#endif
}

void ShowOSErrorBox(std::string_view buf, bool system)
{
  /* Display the error in the best way possible. */
  if (system) {
    ShowMacDialog("OpenTTD has encountered an error", buf, "Quit");
  } else {
    ShowMacDialog(buf, "See the readme for more info.", "Quit");
  }
}

void OSOpenBrowser(const std::string &url)
{
  [ [ NSWorkspace sharedWorkspace ] openURL:[ NSURL URLWithString:[ NSString stringWithUTF8String:url.c_str() ] ] ];
}

std::optional<std::string> GetCurrentLocale(const char *)
{
  NSUserDefaults *defs = [ NSUserDefaults standardUserDefaults ];
  NSArray *languages = [ defs objectForKey:@"AppleLanguages" ];
  NSString *preferredLang = [ languages objectAtIndex:0 ];
  /* preferredLang is either 2 or 5 characters long ("xx" or "xx_YY"). */
 
  std::string retbuf{32, '\0'};
  [ preferredLang getCString:retbuf.data() maxLength:retbuf.size() encoding:NSASCIIStringEncoding ];
  auto end = retbuf.find('\0');
  if (end == 0) return std::nullopt;
  if (end != std::string::npos) retbuf.erase(end);
  return retbuf;
}
 
 
#ifdef WITH_COCOA
std::optional<std::string> GetClipboardContents()
{
  NSPasteboard *pb = [ NSPasteboard generalPasteboard ];
  NSArray *types = [ NSArray arrayWithObject:NSPasteboardTypeString ];
  NSString *bestType = [ pb availableTypeFromArray:types ];
 
  /* Clipboard has no text data available. */
  if (bestType == nil) return std::nullopt;
 
  NSString *string = [ pb stringForType:NSPasteboardTypeString ];
  if (string == nil || [ string length ] == 0) return std::nullopt;
 
  return [ string UTF8String ];
}

void CocoaSetApplicationBundleDir()
{
  extern EnumIndexArray<std::string, Searchpath, Searchpath::End> _searchpaths;
 
  char tmp[MAXPATHLEN];
  CFAutoRelease<CFURLRef> url(CFBundleCopyResourcesDirectoryURL(CFBundleGetMainBundle()));
  if (CFURLGetFileSystemRepresentation(url.get(), true, (unsigned char *)tmp, MAXPATHLEN)) {
    _searchpaths[Searchpath::ApplicationBundleDir] = tmp;
    AppendPathSeparator(_searchpaths[Searchpath::ApplicationBundleDir]);
  } else {
    _searchpaths[Searchpath::ApplicationBundleDir].clear();
  }
}

std::string CocoaGetAppSupportDir()
{
  NSArray *paths = NSSearchPathForDirectoriesInDomains(NSApplicationSupportDirectory, NSUserDomainMask, YES);
  NSString *appSupportPath = [paths firstObject];
 
  return [appSupportPath UTF8String];
}

void CocoaSetupAutoreleasePool()
{
  _ottd_autorelease_pool = [ [ NSAutoreleasePool alloc ] init ];
}

void CocoaReleaseAutoreleasePool()
{
  [ _ottd_autorelease_pool release ];
}
 
#endif

bool IsMonospaceFont(CFStringRef name)
{
  NSFont *font = [ NSFont fontWithName:(__bridge NSString *)name size:0.0f ];
 
  return font != nil ? [ font isFixedPitch ] : false;
}

void MacOSSetThreadName(const std::string &name)
{
  pthread_setname_np(name.c_str());
 
  NSThread *cur = [ NSThread currentThread ];
  if (cur != nil && [ cur respondsToSelector:@selector(setName:) ]) {
    [ cur performSelector:@selector(setName:) withObject:[ NSString stringWithUTF8String:name.c_str() ] ];
  }
}

uint64_t MacOSGetPhysicalMemory()
{
  return [ [ NSProcessInfo processInfo ] physicalMemory ];
}